GC-boehm: extend optimized mode to all array methods (#10406)

vlib/builtin/array.v

@@ -647,7 +647,11 @@ pub fn (data &byte) vbytes(len int) []byte {
 	return unsafe { voidptr(data).vbytes(len) }
 }
 
-// non-pub "noscan" versions of some above functions
+// non-pub versions of array functions
+// that allocale new memory using `GC_MALLOC_ATOMIC()`
+// when `-gc boehm_*_opt` is used. These memory areas are not
+// scanned for pointers.
+
 fn __new_array_noscan(mylen int, cap int, elm_size int) array {
 	cap_ := if cap < mylen { mylen } else { cap }
 	arr := array{
@@ -704,6 +708,26 @@ fn new_array_from_c_array_noscan(len int, cap int, elm_size int, c_array voidptr
 	return arr
 }
 
+// Private function. Doubles array capacity if needed.
+fn (mut a array) ensure_cap_noscan(required int) {
+	if required <= a.cap {
+		return
+	}
+	mut cap := if a.cap > 0 { a.cap } else { 2 }
+	for required > cap {
+		cap *= 2
+	}
+	new_size := cap * a.element_size
+	new_data := vcalloc_noscan(new_size)
+	if a.data != voidptr(0) {
+		unsafe { C.memcpy(new_data, a.data, a.len * a.element_size) }
+		// TODO: the old data may be leaked when no GC is used (ref-counting?)
+	}
+	a.data = new_data
+	a.offset = 0
+	a.cap = cap
+}
+
 // repeat returns a new array with the given array elements repeated given times.
 // `cgen` will replace this with an apropriate call to `repeat_to_depth()`
 
@@ -737,14 +761,83 @@ fn (a array) repeat_to_depth_noscan(count int, depth int) array {
 	return arr
 }
 
-pub fn (a &array) clone_to_depth_noscan(depth int) array {
+// insert inserts a value in the array at index `i`
+fn (mut a array) insert_noscan(i int, val voidptr) {
+	$if !no_bounds_checking ? {
+		if i < 0 || i > a.len {
+			panic('array.insert: index out of range (i == $i, a.len == $a.len)')
+		}
+	}
+	a.ensure_cap_noscan(a.len + 1)
+	unsafe {
+		C.memmove(a.get_unsafe(i + 1), a.get_unsafe(i), (a.len - i) * a.element_size)
+		a.set_unsafe(i, val)
+	}
+	a.len++
+}
+
+// insert_many inserts many values into the array from index `i`.
+[unsafe]
+fn (mut a array) insert_many_noscan(i int, val voidptr, size int) {
+	$if !no_bounds_checking ? {
+		if i < 0 || i > a.len {
+			panic('array.insert_many: index out of range (i == $i, a.len == $a.len)')
+		}
+	}
+	a.ensure_cap_noscan(a.len + size)
+	elem_size := a.element_size
+	unsafe {
+		iptr := a.get_unsafe(i)
+		C.memmove(a.get_unsafe(i + size), iptr, (a.len - i) * elem_size)
+		C.memcpy(iptr, val, size * elem_size)
+	}
+	a.len += size
+}
+
+// prepend prepends one value to the array.
+fn (mut a array) prepend_noscan(val voidptr) {
+	a.insert_noscan(0, val)
+}
+
+// prepend_many prepends another array to this array.
+[unsafe]
+fn (mut a array) prepend_many_noscan(val voidptr, size int) {
+	unsafe { a.insert_many_noscan(0, val, size) }
+}
+
+// pop returns the last element of the array, and removes it.
+fn (mut a array) pop_noscan() voidptr {
+	// in a sense, this is the opposite of `a << x`
+	$if !no_bounds_checking ? {
+		if a.len == 0 {
+			panic('array.pop: array is empty')
+		}
+	}
+	new_len := a.len - 1
+	last_elem := unsafe { &byte(a.data) + new_len * a.element_size }
+	a.len = new_len
+	// NB: a.cap is not changed here *on purpose*, so that
+	// further << ops on that array will be more efficient.
+	return unsafe { memdup_noscan(last_elem, a.element_size) }
+}
+
+// `clone_static_to_depth_noscan()` returns an independent copy of a given array.
+// Unlike `clone_to_depth_noscan()` it has a value receiver and is used internally
+// for slice-clone expressions like `a[2..4].clone()` and in -autofree generated code.
+fn (a array) clone_static_to_depth_noscan(depth int) array {
+	return unsafe { a.clone_to_depth_noscan(depth) }
+}
+
+// recursively clone given array - `unsafe` when called directly because depth is not checked
+[unsafe]
+fn (a &array) clone_to_depth_noscan(depth int) array {
 	mut size := a.cap * a.element_size
 	if size == 0 {
 		size++
 	}
 	mut arr := array{
 		element_size: a.element_size
-		data: if depth > 0 { vcalloc(size) } else { vcalloc_noscan(size) }
+		data: if depth == 0 { vcalloc_noscan(size) } else { vcalloc(size) }
 		len: a.len
 		cap: a.cap
 	}
@@ -765,6 +858,34 @@ pub fn (a &array) clone_to_depth_noscan(depth int) array {
 	}
 }
 
+fn (mut a array) push_noscan(val voidptr) {
+	a.ensure_cap_noscan(a.len + 1)
+	unsafe { C.memmove(&byte(a.data) + a.element_size * a.len, val, a.element_size) }
+	a.len++
+}
+
+// push_many implements the functionality for pushing another array.
+// `val` is array.data and user facing usage is `a << [1,2,3]`
+[unsafe]
+fn (mut a3 array) push_many_noscan(val voidptr, size int) {
+	if a3.data == val && !isnil(a3.data) {
+		// handle `arr << arr`
+		copy := a3.clone()
+		a3.ensure_cap_noscan(a3.len + size)
+		unsafe {
+			// C.memcpy(a.data, copy.data, copy.element_size * copy.len)
+			C.memcpy(a3.get_unsafe(a3.len), copy.data, a3.element_size * size)
+		}
+	} else {
+		a3.ensure_cap_noscan(a3.len + size)
+		if !isnil(a3.data) && !isnil(val) {
+			unsafe { C.memcpy(a3.get_unsafe(a3.len), val, a3.element_size * size) }
+		}
+	}
+	a3.len += size
+}
+
+// reverse returns a new array with the elements of the original array in reverse order.
 fn (a array) reverse_noscan() array {
 	if a.len < 2 {
 		return a
@@ -780,3 +901,15 @@ fn (a array) reverse_noscan() array {
 	}
 	return arr
 }
+
+// grow_cap grows the array's capacity by `amount` elements.
+fn (mut a array) grow_cap_noscan(amount int) {
+	a.ensure_cap_noscan(a.cap + amount)
+}
+
+// grow_len ensures that an array has a.len + amount of length
+[unsafe]
+fn (mut a array) grow_len_noscan(amount int) {
+	a.ensure_cap_noscan(a.len + amount)
+	a.len += amount
+}